Pfthb

How do I verify the value of a regedit query request?

REG QUERY "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /V "HiberbootEnabled" 
IF result == 1 goto turoff
IF result == 0 goto turnon

If you're just wanting to toggle the value betwen 1 and 0, something along these lines may work for you, (as long as you have the appropriate permissions to access/modify the value data).

@Echo Off
Set "DWord="
For /F "Tokens=3" %%A In ('
 Reg Query "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /V "HiberbootEnabled" 2^>Nul
') Do 2>Nul Set /A DWord=1-%%A
If Defined DWord Reg Add "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /V "HiberbootEnabled" /T REG_DWORD /D %DWord% /F>Nul

Use find or findstr to filter the line needed, and then use for /f to read the output

for /f "tokens=3" %%v in ('REG QUERY "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /V "HiberbootEnabled" ^| find "HiberbootEnabled"') do set result=%%v
if "%result%" == "0x1" (
 turnoff
) else (
 turnon
)

There can be found lots of articles in world wide web on how to change the fast startup setting of Windows 8 and later Windows versions.

Here is one more commented batch file solution which must be run as administrator:

@echo off
setlocal EnableExtensions DisableDelayedExpansion

for /F "skip=2 tokens=1-3" %%A in ('%SystemRoot%System32reg.exe query "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /v "HiberBootEnabled" 2^>nul') do (
 if /I "%%A" == "HiberBootEnabled" set /A "HiberBootEnabled=%%C" & goto EvaluateValue
)

for /F "delims=" %%I in ('ver') do set "WindowsVersion=%%I"
echo Fast startup (hibernate boot) setting not found in Windows registry.
echo/
echo %WindowsVersion% does not support fast startup.
goto EndBatch

:EvaluateValue
rem Toggle the hibernate boot setting.
if %HiberBootEnabled% == 0 (set "HiberBootEnabled=1") else set "HiberBootEnabled=0"

rem Change the hibernate boot setting in registry if batch file
rem is executed with elevated permissions of a local administrator.
%SystemRoot%System32reg.exe add "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /f /v "HiberBootEnabled" /t REG_DWORD /d %HiberBootEnabled% >nul
if errorlevel 1 goto ErrorAddValue

if %HiberBootEnabled% == 0 (set "HiberBootEnabled=OFF") else set "HiberBootEnabled=ON"
echo Fast startup (hibernate boot) setting toggled %HiberBootEnabled%.
goto EndBatch

:ErrorAddValue
echo/
echo %~nx0 must be run as administrator to toggle the
echo fast startup (hibernate boot) setting in Windows registry.

:EndBatch
echo/
pause
endlocal

This batch file is designed for being executed on Windows XP / Windows Server 2003 and all newer Windows versions. There is nothing done if Windows does not already have the double word registry value HiberBootEnabled because of not supporting fast startup. It also does nothing if the batch file is executed without elevated privileges of a local administrator required for write access to HKEY_LOCAL_MACHINE registry hive.

Here is also an optimized version using the simple and great method to subtract from 1 the current value of the double word to toggle it as posted by Compo in his answer.

@echo off
setlocal EnableExtensions DisableDelayedExpansion

for /F "skip=2 tokens=1-3" %%A in ('%SystemRoot%System32reg.exe query "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /v "HiberBootEnabled" 2^>nul') do (
 if /I "%%A" == "HiberBootEnabled" set /A "HiberBootEnabled=1-%%C" & goto ToggleValue
)

for /F "delims=" %%I in ('ver') do set "WindowsVersion=%%I"
echo Fast startup (hibernate boot) setting not found in Windows registry.
echo/
echo %WindowsVersion% does not support fast startup.
goto EndBatch

:ToggleValue
rem Change the hibernate boot setting in registry if batch file
rem is executed with elevated permissions of a local administrator.
%SystemRoot%System32reg.exe add "HKLMSYSTEMCurrentControlSetControlSession ManagerPower" /f /v "HiberBootEnabled" /t REG_DWORD /d %HiberBootEnabled% >nul
if errorlevel 1 goto ErrorAddValue

if %HiberBootEnabled% == 0 (set "HiberBootEnabled=OFF") else set "HiberBootEnabled=ON"
echo Fast startup (hibernate boot) setting toggled %HiberBootEnabled%.
goto EndBatch

:ErrorAddValue
echo/
echo %~nx0 must be run as administrator to toggle
echo the hibernate boot setting in Windows registry.

:EndBatch
echo/
pause
endlocal

And even better would be as fifth line according to suggestion by LotPings:

 if /I "%%A" == "HiberBootEnabled" set /A "HiberBootEnabled=!%%C" & goto ToggleValue

This line sets HiberBootEnabled to 0 even if the current value is greater 1.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• 
  call /? .. explains %~nx0 (name of batch file with extension)


• echo /?


• endlocal /?


• for /?


• goto /?


• if /?


• pause /?


• reg /?


• reg add /?


• reg query /?


• rem /?


• set /?


• setlocal /?