Pfthb

I have created a form to allow a user to change their password.

I created a recordset and used edit/update to save it in a query, but the new password is not being saved in the query.

My code is as follows:

Private Sub txtNewPass2_AfterUpdate()

Dim db As DAO.Database
Dim rst As DAO.Recordset

Set db = CurrentDb
Set rst = db.OpenRecordset("qryUsers", dbOpenDynaset)

 If Me.txtNewPass1 = Me.txtNewPass2 Then

 rst.MoveFirst
 Do Until rst.EOF
 If rst!NName = CboUserName.Column(0) Then
 rst.Edit
 rst!Password = txtNewPass2.Value
 rst.Update
 End If
 rst.MoveNext
 Loop

 DoCmd.Openform("frmLogin")

 Else: MsgBox "Passwords not Matching"

 End If
End Sub

The expression:

DoCmd.Openform("frmLogin")

Will result in a syntax error, as the parentheses surrounding the arguments are not required when the value returned by the function is not used.

However, you may find it cleaner to simply execute a SQL statement to perform the update, rather than iterating over the recordset, i.e.:

Private Sub txtNewPass2_AfterUpdate()
 If txtNewPass1 = txtNewPass2 Then
 With CurrentDb.CreateQueryDef("", "UPDATE qryUsers SET qryUsers.Password = ?pwd WHERE qryUsers.NName = ?usr")
 .Parameters(0) = txtNewPass2
 .Parameters(1) = CboUserName.Column(0)
 .Execute
 End With
 DoCmd.Openform "frmLogin"
 Else
 MsgBox "Passwords not Matching"
 End If
End Sub

Using parameters of course to account for users better known as Bobby Tables.